Ticket #543: http_keepalive_proxy-2.2.t

#!/usr/bin/perl

# (C) Maxim Dounin
# (C) Markus Linnala

# Tests keepalive is kept regardless proxy type.

###############################################################################

use warnings;
use strict;

use Test::More;

use IO::Socket::INET;
use Socket qw/ CRLF /;

BEGIN { use FindBin; chdir($FindBin::Bin); }

use lib 'lib';
use Test::Nginx;

###############################################################################

select STDERR; $| = 1;
select STDOUT; $| = 1;

plan(skip_all => 'win32') if $^O eq 'MSWin32';

my $t = Test::Nginx->new()->has(qw/http proxy upstream_keepalive sub/)->plan(2)
        ->write_file_expand('nginx.conf', <<'EOF');

%%TEST_GLOBALS%%

daemon off;

events {
}

http {
    %%TEST_GLOBALS_HTTP%%

    upstream backend {
        server 127.0.0.1:8081;
    }

    server {
        listen       127.0.0.1:8080;
        server_name  localhost;

        location / {
            proxy_pass http://backend;
            proxy_http_version 1.1;
            proxy_set_header Connection "";
        }
    }
}

EOF

$t->run_daemon(\&http_daemon);
$t->run()->waitforsocket('127.0.0.1:8081')
        or die "Can't start test backend";

###############################################################################

like(http_ka('/','1.0'), qr/Connection: keep-alive/, 'keepalive/1.0 proxy chunked');
like(http_cl('/','1.0'), qr/Connection: close/, 'close/1.0 proxy chunked');

like(http_ka('/','1.1'), qr/Connection: keep-alive/, 'keepalive/1.1 proxy chunked');
like(http_cl('/','1.1'), qr/Connection: close/, 'close/1.1 proxy chunked');

###############################################################################

sub http_ka {
        my ($q, $p) = @_;
        my_http(<<EOF, 'sleep' => 0.1);
GET $q HTTP/$p
Host: localhost
Connection: Keep-Alive

EOF
}

sub http_cl {
        my ($q, $p) = @_;
        my_http(<<EOF, 'sleep' => 0.1);
GET $q HTTP/$p
Host: localhost
Connection: close

EOF
}

###############################################################################

sub my_http {
        my ($request, %extra) = @_;
        my $reply;

        eval {
                local $SIG{ALRM} = sub { die "timeout\n" };
                local $SIG{PIPE} = sub { die "sigpipe\n" };
                alarm(5);

                my $s = $extra{socket} || IO::Socket::INET->new(
                        Proto => 'tcp',
                        PeerAddr => '127.0.0.1:8080',
                )
                        or die "Can't connect to nginx: $!\n";

                log_out($request);
                $s->print($request);

                select undef, undef, undef, $extra{sleep} if $extra{sleep};
                return '' if $extra{aborted};

                if ($extra{body}) {
                        log_out($extra{body});
                        $s->print($extra{body});
                }

                # Done writing
                $s->shutdown(1);

                local $/;
                $reply = $s->getline();

                alarm(0);
        };
        alarm(0);
        if ($@) {
                log_in("died: $@");
                return undef;
        }

        log_in($reply);
        return $reply;
}

sub http_daemon {
        my $server = IO::Socket::INET->new(
                Proto => 'tcp',
                LocalHost => '127.0.0.1:8081',
                Listen => 5,
                Reuse => 1
        )
                or die "Can't create listening socket: $!\n";

        # dumb server which is able to keep connections alive

        while (my $client = $server->accept()) {
                $client->autoflush(1);

                while (1) {
                        my $headers = '';
                        my $uri = '';

                        while (<$client>) {
                                $headers .= $_;
                                last if (/^\x0d?\x0a?$/);
                        }

                        last if $headers eq '';

                        $uri = $1 if $headers =~ /^\S+\s+([^ ]+)\s+HTTP/i;

                        print { $client }
                                "HTTP/1.1 200 OK" . CRLF .
                                "Transfer-Encoding: chunked" . CRLF .
                                CRLF .
                                "a" . CRLF .
                                "finished" . CRLF .
                                CRLF . "0" . CRLF . CRLF;

                        last;
                }

                close $client;
        }
}

###############################################################################