Ticket #543: http_keepalive_proxy.t

#!/usr/bin/perl

# (C) Maxim Dounin
# (C) Markus Linnala

# Tests keepalive is kept regardless proxy type.

###############################################################################

use warnings;
use strict;

use Test::More;

use IO::Socket::INET;
use Socket qw/ CRLF /;

BEGIN { use FindBin; chdir($FindBin::Bin); }

use lib 'lib';
use Test::Nginx;

###############################################################################

select STDERR; $| = 1;
select STDOUT; $| = 1;

plan(skip_all => 'win32') if $^O eq 'MSWin32';

my $t = Test::Nginx->new()->has(qw/http proxy upstream_keepalive sub/)->plan(16)
        ->write_file_expand('nginx.conf', <<'EOF');

%%TEST_GLOBALS%%

daemon off;

events {
}

http {
    %%TEST_GLOBALS_HTTP%%

    upstream backend {
        server 127.0.0.1:8081;
        keepalive 1;
    }

    server {
        listen       127.0.0.1:8080;
        server_name  localhost;

        location /cl {
            proxy_pass http://backend;
        }
        location /ka {
            proxy_pass http://backend;
            proxy_read_timeout 2s;
            proxy_http_version 1.1;
            proxy_set_header Connection "";
        }

        location /cl-ch {
            sub_filter foo bar;
            sub_filter_types *;
            proxy_pass http://backend;
        }
        location /ka-ch {
            sub_filter foo bar;
            sub_filter_types *;
            proxy_pass http://backend;
            proxy_read_timeout 2s;
            proxy_http_version 1.1;
            proxy_set_header Connection "";
        }
    }
}

EOF

$t->run_daemon(\&http_daemon);
$t->run()->waitforsocket('127.0.0.1:8081')
        or die "Can't start test backend";

###############################################################################

sub http_ka {
        my ($q, $p) = @_;
        my_http(<<EOF, 'sleep' => 0.1);
GET $q HTTP/$p
Host: localhost
Connection: Keep-Alive

EOF
}

sub http_cl {
        my ($q, $p) = @_;
        my_http(<<EOF, 'sleep' => 0.1);
GET $q HTTP/$p
Host: localhost
Connection: close

EOF
}

###############################################################################

like(http_ka('/ka','1.0'), qr/Connection: keep-alive/, 'ka-ka/1.0');
like(http_cl('/ka','1.0'), qr/Connection: close/, 'ka-cl/1.0');

like(http_ka('/ka','1.1'), qr/Connection: keep-alive/, 'ka-ka/1.1');
like(http_cl('/ka','1.1'), qr/Connection: close/, 'ka-cl/1.1');

like(http_ka('/cl','1.0'), qr/Connection: keep-alive/, 'cl-ka/1.0');
like(http_cl('/cl','1.0'), qr/Connection: close/, 'cl-cl/1.0');

like(http_ka('/cl','1.1'), qr/Connection: keep-alive/, 'cl-ka/1.1');
like(http_cl('/cl','1.1'), qr/Connection: close/, 'cl-cl/1.1');

like(http_ka('/ka-ch','1.0'), qr/Connection: keep-alive/, 'ka-ch-ka/1.0'); #
like(http_cl('/ka-ch','1.0'), qr/Connection: close/, 'ka-ch-cl/1.0');

like(http_ka('/ka-ch','1.1'), qr/Connection: keep-alive/, 'ka-ch-ka/1.1');
like(http_cl('/ka-ch','1.1'), qr/Connection: close/, 'ka-ch-cl/1.1');

like(http_ka('/cl-ch','1.0'), qr/Connection: keep-alive/, 'cl-ch-ka/1.0'); #
like(http_cl('/cl-ch','1.0'), qr/Connection: close/, 'cl-ch-cl/1.0');

like(http_ka('/cl-ch','1.1'), qr/Connection: keep-alive/, 'cl-ch-ka/1.1');
like(http_cl('/cl-ch','1.1'), qr/Connection: close/, 'cl-ch-cl/1.1');

###############################################################################

sub my_http {
        my ($request, %extra) = @_;
        my $reply;

        eval {
                local $SIG{ALRM} = sub { die "timeout\n" };
                local $SIG{PIPE} = sub { die "sigpipe\n" };
                alarm(5);

                my $s = $extra{socket} || IO::Socket::INET->new(
                        Proto => 'tcp',
                        PeerAddr => '127.0.0.1:8080',
                )
                        or die "Can't connect to nginx: $!\n";

                log_out($request);
                $s->print($request);

                select undef, undef, undef, $extra{sleep} if $extra{sleep};
                return '' if $extra{aborted};

                if ($extra{body}) {
                        log_out($extra{body});
                        $s->print($extra{body});
                }

                # Done writing
                $s->shutdown(1);

                local $/;
                $reply = $s->getline();

                alarm(0);
        };
        alarm(0);
        if ($@) {
                log_in("died: $@");
                return undef;
        }

        log_in($reply);
        return $reply;
}

sub http_daemon {
        my $server = IO::Socket::INET->new(
                Proto => 'tcp',
                LocalHost => '127.0.0.1:8081',
                Listen => 5,
                Reuse => 1
        )
                or die "Can't create listening socket: $!\n";

        my $ccount = 0;
        my $rcount = 0;

        # dumb server which is able to keep connections alive

        while (my $client = $server->accept()) {
                $client->autoflush(1);
                $ccount++;

                while (1) {
                        my $headers = '';
                        my $uri = '';

                        while (<$client>) {
                                $headers .= $_;
                                last if (/^\x0d?\x0a?$/);
                        }

                        last if $headers eq '';
                        $rcount++;

                        $uri = $1 if $headers =~ /^\S+\s+([^ ]+)\s+HTTP/i;

                        if (1) {
                                print { $client }
                                        "HTTP/1.1 200 OK" . CRLF .
                                        "X-Request: $rcount" . CRLF .
                                        "X-Connection: $ccount" . CRLF .
                                        "Content-Length: 10000" . CRLF . CRLF;
                                print { $client } ('X' x 10000)
                                        unless $headers =~ /^HEAD/i;

                                last;
                        }
                }

                close $client;
        }
}

###############################################################################